Report.Circle 方法 (Access)

当 Print 事件发生时,Circle 方法在 Report 对象上绘制圆、椭圆或圆弧。

语法

表达式。圆圈 (步骤 (x、y) 、 半径、 颜色、 开始、 结束、 纵横比)

表达式 表示 Report 对象的变量。

参数

名称 数据类型 说明
步骤 关键字 指示圆、椭圆或圆弧的中心相对于对象参数的 CurrentX 和 CurrentY 属性的当前设置给出的当前坐标。
(x、y) Single 指示圆、椭圆或圆弧的中心点的坐标。Scale 参数指定的 Report 对象的 ScaleMode、ScaleLeft、ScaleTop、ScaleHeight 和 ScaleWidth) (Scale 属性确定所使用的度量单位。
Radius Single 指示圆、椭圆或圆弧的半径。Scale 参数指定的 Report 对象 (ScaleMode、ScaleLeft、ScaleTop、ScaleHeight 和 ScaleWidth) 的 Scale 属性确定所使用的度量单位。 默认情况下,距离以 twips 为单位进行测量。
Color Long 表示圆圈轮廓的 RGB (红绿蓝) 颜色。 如果省略此参数,则使用 前景色 属性的值。 此外可以使用 QBColor 函数的 RGB 函数来指定颜色。
Start Single 绘制部分圆或椭圆时, 开始 参数指定圆弧起始位置) 弧度为单位的 (。 Start 参数的默认值为 0 弧度。 范围为 -2 pi 弧度到 2 pi 弧度。
End Single 绘制部分圆或椭圆时, End 参数以弧度) 圆弧的结束位置为单位指定 (。 End 参数的默认值为 2 pi 弧度。 范围为 -2 pi 弧度到 2 pi 弧度。
方面 Single 指示圆的纵横比。 默认值是 1.0,表示在任何屏幕上都是一个正圆(而不是椭圆)。

备注

仅在报表部分的事件属性或报表的 OnPage 事件属性指定的事件过程或宏中使用此方法。

绘制部分圆或椭圆时,如果 Start 参数为负,则 Circle 方法会将半径绘制到 Start 参数指定的位置,并将角度视为正。 如果 End 参数为负,则 Circle 方法会将半径绘制到 End 参数指定的位置,并再次将角度视为正。 Circle 方法总以逆时针方向(正向)进行绘制。

若要填充一个圆,请设置报表的 FillColor 和 FillStyle 属性。 只有封闭的图形才能进行填充。 封闭的图形包括圆、椭圆和扇形,这些弧形的两端都由半径线相连。

绘制饼图切片时,如果您需要绘制角度为 0 的半径以向右形成水平线段,请为 Start 参数指定一个非常小的负值,而不是 0。 例如,可以为 开始参数 指定 -.00000001。

在语法当中可以忽略某个参数,但如果该参数后面还有下一个参数,就必须在语法中包括该参数的逗号。 如果省略尾随参数,请勿在指定的最后一个参数后面使用任何逗号。

用于绘制圆、椭圆或圆弧的线条的宽度取决于 DrawWidth 属性设置。 在背景上绘制圆圈的方式取决于 DrawMode 和 DrawStyle 属性的设置。

在应用 Circle 方法时,CurrentX 和 CurrentY 属性设为由 x 和 y 参数指定的中心点。

示例

下面的示例使用 Circle 方法来画一个圆,然后在这个圆中创建一个扇形,并将它的颜色变为红色。

若要在 Microsoft Access 中试用这一示例,请先创建一个新的报表。 将“主体”节的 OnPrint 属性设置为 [事件过程]。 在报表模块中输入以下代码,然后切换到打印预览。

Private Sub Detail_Print(Cancel As Integer, PrintCount As Integer) 
    Const conPI = 3.14159265359 
    Dim sngHCtr As Single, sngVCtr As Single 
    Dim sngRadius As Single 
    Dim sngStart As Single, sngEnd As Single 
 
    sngHCtr = Me.ScaleWidth / 2     ' Horizontal center. 
    sngVCtr = Me.ScaleHeight / 2     ' Vertical center. 
    sngRadius = Me.ScaleHeight / 3     ' Circle radius. 
    ' Draw circle. 
    Me.Circle(sngHCtr, sngVCtr), sngRadius 
    sngStart = -0.00000001             ' Start of pie slice. 
    sngEnd = -2 * conPI / 3             ' End of pie slice. 
    Me.FillColor = RGB(255,0,0)     ' Color pie slice red. 
    Me.FillStyle = 0                     ' Fill pie slice. 
    ' Draw pie slice within circle. 
    Me.Circle(sngHCtr, sngVCtr), sngRadius, , sngStart, sngEnd 
End Sub

支持和反馈

有关于 Office VBA 或本文档的疑问或反馈? 请参阅 Office VBA 支持和反馈,获取有关如何接收支持和提供反馈的指南。