返回一个 Range 对象,它表示指定区域以外的一个区域。
语法
表达式。RowIndex、ColumnIndex) (项
expression 一个表示 Range 对象的变量。
参数
| 名称 | 必需/可选 | 数据类型 | 说明 |
|---|---|---|---|
| RowIndex | 必需 | Variant | 如果提供第二个参数,则为要返回的单元格的相对行号。 如果未提供第二个参数,则为要返回的子区域的索引。 |
| ColumnIndex | 可选 | Variant | 要返回的单元格的相对列号。 |
备注
如果 表达式 不是包含单个单元格集合的区域,例如,由于 is 已通过 Columns 成员获得,则提供第二个参数是非法的,将导致错误 1004。
Range 的默认成员使用参数将调用转发到 Item 成员。 因此,和 someRange(1)someRange(1,1) 分别相当于 someRange.Item(1)someRange.Item(1,1)和 。
RowIndex 和 ColumnIndex 参数是 Areas 成员返回的范围第一个区域的左上角单元格的相对从 1 开始的偏移量,即对于范围Union(someSheet.Range("Z4:AA6"), someSheet.Range("A1:C3")),Item(1,1)将返回地址为 $Z$4 的范围。
ColumnIndex 可以作为数字索引提供,也可以作为列地址字符串提供,如 A1 表示法,即"A"引用数字索引1和 "AA"27.
通过提供适当的参数,可以使用 Item 属性引用原始范围之外的单元格,例如 Item(3,3) 将返回该区域someSheet.Range("B2:C3")的单元格"D4"。
仅提供一个参数时返回的范围取决于范围的性质:
对于由单元格和范围成员返回的由单个单元格组成的区域,项目返回单个单元格。 与二维数组一样,从左到右而不是从上到下枚举范围的第一个区域时,参数 RowIndex 引用索引。 如果 RowIndex 大于区域的第一个区域中的单元格数,则枚举就像该区域向下扩展一样。
对于由行返回的由行范围组成的区域,Item 返回行范围。 参数 RowIndex 是从范围第一行到上到下的从 1 开始的偏移量。
对于由列范围组成的范围,如 Columns 返回的值, Item 返回列范围。 参数 RowIndex 是从第一列到左到右方向的从 1 开始的偏移量。 在这种情况下,也可以将索引作为列地址字符串提供。
示例
下面的示例显示了如果同时提供了这两个参数,将返回哪个单元格。
Public Sub PrintAdresses()
Dim exampleRange As Excel.Range
With ThisWorkbook.Worksheets("ExampleSheet")
Set exampleRange = Application.Union(.Range("B2:D4"), .Range("A1"), .Range("Z1:AA20"))
End With
Debug.Print exampleRange.Item(1,1).Address 'Prints "$B$2"
Debug.Print exampleRange.Item(2,4).Address 'Prints "$E$3"
Debug.Print exampleRange.Item(20,40).Address 'Prints "$AO$21"
Debug.Print exampleRange.Item(2,"D").Address 'Prints "$E$3"
Debug.Print exampleRange.Item(20,"AN").Address 'Prints "$AO$21"
End Sub
下面的示例演示了在仅提供一个参数时,对于不同类型的范围,将返回哪些子范围。
Public Sub PrintAdresses()
Dim exampleRange As Excel.Range
With ThisWorkbook.Worksheets("ExampleSheet")
Set exampleRange = Application.Union(.Range("B2:D4"), .Range("A1"), .Range("Z1:AA20"))
End With
Debug.Print exampleRange.Cells.Item(1).Address 'Prints "$B$2"
Debug.Print exampleRange.Cells.Item(2).Address 'Prints "$C$2"
Debug.Print exampleRange.Cells.Item(4).Address 'Prints "$B$3"
Debug.Print exampleRange.Cells.Item(10).Address 'Prints "$B$5"
Debug.Print exampleRange.Rows.Item(1).Address 'Prints "$B$2:$D$2"
Debug.Print exampleRange.Rows.Item(10).Address 'Prints "$B$11:$D$11"
Debug.Print exampleRange.Columns.Item(1).Address 'Prints "$B$2:$B$4"
Debug.Print exampleRange.Columns.Item(10).Address 'Prints "$K$2:$K$4"
Debug.Print exampleRange.Columns.Item("A").Address 'Prints "$B$2:$B$4"
Debug.Print exampleRange.Columns.Item("J").Address 'Prints "$K$2:$K$4"
End Sub
支持和反馈
有关于 Office VBA 或本文档的疑问或反馈? 请参阅 Office VBA 支持和反馈,获取有关如何接收支持和提供反馈的指南。