Excel) (Range.Text 属性

返回指定对象的格式文本。 只读 String。

语法

表达式。文本

expression 一个表示 Range 对象的变量。

备注

Text 属性最常用于一个单元格的范围。 如果区域包含多个单元格,则 Text 属性将返回 Null,除非区域中的所有单元格的内容和格式都相同。

如果单元格的内容宽于可用于显示的宽度,则 Text 属性将修改显示值。

属性差异示例

此示例说明包含带格式的数字的单元格的 Text 和 Value 属性之间的差异。

Option Explicit

Public Sub DifferencesBetweenValueAndTextProperties()
    Dim cell As Range
    Set cell = Worksheets("Sheet1").Range("A1")
    cell.Value = 1198.3
    cell.NumberFormat = "$#,##0_);($#,##0)"
    
    MsgBox "'" & cell.Value & "' is the value." 'Returns: "'1198.3' is the value."
    MsgBox "'" & cell.Text & "' is the text."    'Returns: "'$1,198' is the text."
End Sub

文本宽度差异

当列宽度不够时,包含数值的单元格的显示值可能会被修改。 下面的示例使用两列进行演示。 第一列的宽度足以显示值。 应用格式,然后输入显示完整值的值。 第二列的宽度减小,以便在复制单元格时太窄,导致显示值变和。

Public Sub TextWidthDifferences()
    
    Dim wideColumn As Range
    Set wideColumn = Sheet1.Range("B2")
    wideColumn.Value = "Wide Enough Column"
    wideColumn.Columns.AutoFit
    
    Sheet1.Range("B3").Value2 = 123456789
    
    Const CurrencyWith2DecimalsFormat As String = "$#,##0.00"
    Dim currencyCell As Range
    Set currencyCell = Sheet1.Range("B4")
    currencyCell.Value2 = 1234.56
    currencyCell.NumberFormat = CurrencyWith2DecimalsFormat
    
    Dim narrowColumn As Range
    Set narrowColumn = Sheet1.Range("C2")
    narrowColumn.Value = "Reduced Width Column"
    narrowColumn.ColumnWidth = 7.5
    
    Sheet1.Range("B3:B4").AutoFill Destination:=Sheet1.Range("B3:C4"), Type:=XlAutoFillType.xlFillDefault
    Debug.Print Sheet1.Range("C3").Text
    Debug.Print Sheet1.Range("C4").Text
End Sub

支持和反馈

有关于 Office VBA 或本文档的疑问或反馈? 请参阅 Office VBA 支持和反馈,获取有关如何接收支持和提供反馈的指南。