PowerPoint) (ConnectorFormat 对象

包含应用于连接符的属性和方法。

备注

连接符是用于连接其他两个形状的线,所连接的位置叫做连接结点。 如果重新排列已连接的形状,那么连接符的几何形状将自动调整,以使重新排列的形状仍保持连接。

使用 ConnectorFormat 属性返回一个 ConnectorFormat 对象。 使用 BeginConnect 和 EndConnect 方法将连接线端点附加到文档中的其他形状。 RerouteConnections 方法用于自动查找连接器连接两个形状之间的最短路径。 使用 连接器 属性若要查看某个形状是否为连接符。

请注意,向 Shapes 集合添加一个连接符,但当连接符的终点连接到集合中其他形状,大小和位置会自动调整时会指定大小和位置。 因此,如果打算用连接符连接其他形状时,初始大小和位置就是无关紧要的。 同样,您指定要将连接符连接到当连接符,形状上的连接结点,但连接后用 RerouteConnections 方法可能会更改连接符,使原来选择的连接的站点不相关的连接结点。

连接结点通常按下表所示的规则进行编号。

形状类型 连接结点编号方案
自选形状、艺术字、图片和 OLE 对象 连接结点从顶部开始按逆时针进行编号。
任意多边形 连接结点为顶点,与顶点编号相对应。

示例

下例向 myDocument 中添加两个矩形并且用曲线连接符连接矩形。

Set myDocument = ActivePresentation.Slides(1)

Set s = myDocument.Shapes

Set firstRect = s.AddShape(msoShapeRectangle, 100, 50, 200, 100)

Set secondRect = s.AddShape(msoShapeRectangle, 300, 300, 200, 100)

With s.AddConnector(msoConnectorCurve, 0, 0, 0, 0).ConnectorFormat

    .BeginConnect ConnectedShape:=firstRect, ConnectionSite:=1

    .EndConnect ConnectedShape:=secondRect, ConnectionSite:=1

    .Parent.RerouteConnections

End With

要算出一个复杂形状上各连接结点的编号,可以打开宏录制器并对形状进行试验操作,然后查看录下的代码;也可以创建一个形状并选中它,然后运行以下示例。 这段代码将对每个连接结点进行编号并连接一个连接符。

Set mainshape = ActiveWindow.Selection.ShapeRange(1)

With mainshape

    bx = .Left + .Width + 50

    by = .Top + .Height + 50

End With

With ActiveWindow.View.Slide

    For j = 1 To mainshape.ConnectionSiteCount

        With .Shapes.AddConnector(msoConnectorStraight, bx, by, bx + 50, by + 50)

            .ConnectorFormat.EndConnect mainshape, j

            .ConnectorFormat.Type = msoConnectorElbow

            .Line.ForeColor.RGB = RGB(255, 0, 0)

            l = .Left

            t = .Top

        End With

        With .Shapes.AddTextbox(msoTextOrientationHorizontal, l, t, 36, 14)

            .Fill.Visible = False

            .Line.Visible = False

            .TextFrame.TextRange.Text = j

        End With

    Next j

End With

另请参阅

PowerPoint 对象模型引用

支持和反馈

有关于 Office VBA 或本文档的疑问或反馈? 请参阅 Office VBA 支持和反馈,获取有关如何接收支持和提供反馈的指南。